Dos/Windows ping utility for multiple hosts

[Taz]

Does anybody know of a simple ping utility for DOS or Windows that can ping multiple hosts (via a supplied file of simply copying/pasting a list of hosts) and that can simply display if the hosts responded or not?

The kind of output i'm after is along the lines of:

host1 - alive
host2 - alive
host3 - dead
host4 - alive
host5 - dead
host6 - dead

...and so on.

The standard DOS ping utility in XP/2003 produces too much output and is hard to process easily as i've scripted it to read the list of hosts from a file and that list contains many machines.

[Jay]

maybe Look@lan may help you?

http://www.lookatlan.com/download_lal.html

[ikonia]

something like network notepad may also be of use

[Paul Adams]

@echo off
for /f %%i in (hosts.txt) do call ::pingit %%i

:pingit
if "%1"=="" goto END
ping -n 1 %1 >nul
if errorlevel 1 goto FAIL
echo %1 - alive
goto END

:FAIL
echo %1 - dead

:END

Save that into a batch file and have your list of machine names in a plain text file HOSTS.TXT, that should give the output you want?

[ikonia]

ahhh so : is how you handle functions in a dos based script.

Thank you for that Paul

[Taz]

@echo off
for /f %%i in (hosts.txt) do call ::pingit %%i

:pingit
if "%1"=="" goto END
ping -n 1 %1 >nul
if errorlevel 1 goto FAIL
echo %1 - alive
goto END

:FAIL
echo %1 - dead

:END

Save that into a batch file and have your list of machine names in a plain text file HOSTS.TXT, that should give the output you want?

Thanks a lot for that, Paul. I shall try it out.

[Taz]

Paul, it worked like a champ. I created a file called pinger2.bat with the following:

@echo off
echo Pinger Utility V2.0
echo.

if "%1" NEQ "" goto :checkfile
echo Usage: pinger2 hosts_file
echo.
goto :eof

:checkfile
if exist %1 goto :doping
echo Input file does not exist
echo.
goto :eof

:doping
for /f "tokens=*" %%I in (%1) do call ::pingmachine %%I
goto :eof

:pingmachine
ping -n 1 %1 >nul
if errorlevel 1 goto FAIL
echo %1 - alive
goto END

:FAIL
echo %1 - dead

:END
::DONE

I just do a bit of parameter checking at the beginning but the rest is essentially Paul's code. I then created an input hosts file called 'myfile.txt' with the following contents:

127.0.0.1
blahblah

I then ran the batch file as follows:

C:\Temp>pinger2 myfile.txt

This produces the following output:

Pinger Utility V2.0

127.0.0.1 - alive
blahblah - dead

Hurrah!