How to get network interfaces media state

[Taz]

I've managed to create a VBscript to get a load of network parameters for the network interfaces on a Windows machine that includes things like the MAC address, link speed, duplex mode, etc for a project that i'm working. This is running fine.

However, i've been asked to get one more piece of information for each network interface on a Windows machine: the link status - i.e. whether the NIC is actually connected to anything or not.

If I type 'ipconfig /all' I see a 'Media state.....: Media Disconnected' line for network interfaces that are not connected. However, I don't see a similar line for those that are connected.

Thus, is there a way to programmatically get the link status in VBscript? I'd want to be able to loop through and get the 'link status' property of each NIC and simply translate this to "UP" or "DOWN".

I have looked at the IPEnabled property of Win32_NetworkAdapterConfiguration class but this does not tell me the link status but just returns TRUE or FALSE if the NIC is bound or not. I'm really after the physical link status.

[aidanjt]

Isn't the lack of 'media state' information enough to state that it's up?..

[Jay]

' ------ SCRIPT CONFIGURATION ------
strComputer = "."
' ------ END CONFIGURATION ---------
set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
set colNAs = objWMI.InstancesOf("Win32_NetworkAdapter")
for each objNA in colNAs
 Wscript.Echo objNA.Name
 Wscript.Echo " Description: " & objNA.Description
 Wscript.Echo " Product Name: " & objNA.ProductName
 Wscript.Echo " Manufacturer: " & objNA.Manufacturer
 Wscript.Echo " Adapter Type: " & objNA.AdapterType
 Wscript.Echo " AutoSense: " & objNA.AutoSense
 Wscript.Echo " MAC Address: " & objNA.MACAddress
 Wscript.Echo " Maximum Speed:" & objNA.MaxSpeed
 Wscript.Echo " Conn Status: " & objNA.NetConnectionStatus
 Wscript.Echo " Service Name: " & objNA.ServiceName
 Wscript.Echo " Speed: " & objNA.Speed

 set colNACs = objWMI.ExecQuery(" select * from " & _
 " Win32_NetworkAdapterConfiguration " & _
 " where Index = " & objNA.Index)
 ' There should only be one item in colNACs
 for each objNAC in colNACs
 if IsArray(objNAC.IPAddress) then
 for each strAddress in objNAC.IPAddress
 Wscript.Echo " Network Addr: " & strAddress
 next
 end if
 Wscript.Echo " IP Metric: " & objNAC.IPConnectionMetric
 Wscript.Echo " IP Enabled: " & objNAC.IPEnabled
 Wscript.Echo " Filter: " & objNAC.IPFilterSecurityEnabled
 Wscript.Echo " Port Security:" & objNAC.IPPortSecurityEnabled
 if IsArray(objNAC.IPSubnet) then
 for each strAddress in objNAC.IPSubnet
 Wscript.Echo " Subnet Mask: " & strAddress
 next
 end if
 if IsArray(objNAC.DefaultIPGateway) then
 for each strAddress in objNAC.DefaultIPGateway
 Wscript.Echo " Gateway Addr: " & strAddress
 next
 end if
 Wscript.Echo " Database Path:" & objNAC.DatabasePath
 Wscript.Echo " DHCP Enabled: " & objNAC.DHCPEnabled
 Wscript.Echo " Lease Expires:" & objNAC.DHCPLeaseExpires
 Wscript.Echo " Lease Obtained: " & objNAC.DHCPLeaseObtained
 Wscript.Echo " DHCP Server: " & objNAC.DHCPServer
 Wscript.Echo " DNS Domain: " & objNAC.DNSDomain
 Wscript.Echo " DNS For WINS: " & objNAC.DNSEnabledForWINSResolution
 Wscript.Echo " DNS Host Name:" & objNAC.DNSHostName
 if IsArray(objNAC.DNSDomainSuffixSearchorder) then
 for each strName in objNAC.DNSDomainSuffixSearchOrder
 Wscript.Echo " DNS Suffix Search Order: " & strName
 next
 end if
 if IsArray(objNAC.DNSServerSearchOrder) then
 for each strName in objNAC.DNSServerSearchOrder
 Wscript.Echo " DNS Server Search Order: " & strName
 next
 end if
 Wscript.Echo " Domain DNS Reg Enabled: " & _
 objNAC.DomainDNSRegistrationEnabled
 Wscript.Echo " Full DNS Reg Enabled: " & _
 objNAC.FullDNSRegistrationEnabled
 Wscript.Echo " LMHosts Lookup: " & objNAC.WINSEnableLMHostsLookup
 Wscript.Echo " WINS Lookup File: " & objNAC.WINSHostLookupFile
 Wscript.Echo " WINS Scope ID: " & objNAC.WINSScopeID
 Wscript.Echo " WINS Primary Server: " & objNAC.WINSPrimaryServer
 Wscript.Echo " WINS Secondary: " & objNAC.WINSSecondaryServer
 next

 WScript.Echo
next

There is a lot of info you can get from this script. If you pull it apart I am sure you can work it out.

[Taz]

Thanks, Jay. I had just started to look at the Win32_NetworkAdapter class this afternoon and was struggling to get a working script! I think I can get what I need from the script you have supplied.

[Jay]

have a look at objItem.NetConnectionStatus

The info you need is

0 Disconnected

1 Connecting

2 Connected

3 Disconnecting

4 Hardware not present

5 Hardware disabled

6 Hardware malfunction

7 Media disconnected

8 Authenticating

9 Authentication succeeded

10 Authentication failed



this is a better script, the other was a bit of a mess

'  --------------------------------------------------------------' 
Option Explicit
Dim objWMIService, ObjItem
Dim GuyMessage, strComputer, colItems
'On Error Resume Next
strComputer = "."

Set objWMIService = GetObject("winmgmts:\\" & strComputer &  "\root\cimv2")
Set colItems = objWMIService.ExecQuery ("Select * from Win32_NetworkAdapter",,48)

For Each objItem in colItems

If objItem.MACAddress <> "" Then
' Remove objItem's that you do not want.
WScript.Echo "Name: " & objItem.Name & vbCRLf & _ 
"Net Connection ID: " & objItem.NetConnectionID & vbCRLf & _ 
"Net Connection Status: " & objItem.NetConnectionStatus & vbCRLf & _ 
"Adapter Type: " & objItem.AdapterType & vbCRLf & _ 
"MAC Address: " & objItem.MACAddress & vbCRLf & _ 
"Availability: " & objItem.Availability & vbCRLf & _
"" & vbCRLf & _
"Computer Name: " & objItem.SystemName & vbCRLf & _ 
"AutoSense: " & objItem.AutoSense & vbCRLf & _ 
"ManagerErrorCode: " & objItem.ConfigManagerErrorCode & vbCRLf & _ 
"ManagerUserConfig: " & objItem.ConfigManagerUserConfig & vbCRLf & _ 
"DeviceID: " & objItem.DeviceID & vbCRLf & _ 
"ErrorCleared: " & objItem.ErrorCleared & vbCRLf & _ 
"ErrorDescription: " & objItem.ErrorDescription & vbCRLf & _ 
"Index: " & objItem.Index & vbCRLf & _ 
"InterfaceIndex: " & objItem.InterfaceIndex & vbCRLf & _ 
"LastErrorCode: " & objItem.LastErrorCode & vbCRLf & _ 
"Manufacturer: " & objItem.Manufacturer & vbCRLf & _ 
"MaxNumberControlled: " & objItem.MaxNumberControlled & vbCRLf & _ 
"MaxSpeed: " & objItem.MaxSpeed & vbCRLf & _ 
"NetworkAddresses: " & objItem.NetworkAddresses & vbCRLf & _ 
"PermanentAddress: " & objItem.PermanentAddress & vbCRLf & _ 
"PNPDeviceID: " & objItem.PNPDeviceID & vbCRLf & _ 
"Power Mngmnt: " & objItem.PowerManagementCapabilities & vbCRLf & _ 
"Power Supported: " & objItem.PowerManagementSupported & vbCRLf & _
"ServiceName: " & objItem.ServiceName & vbCRLf & _ 
"Speed: " & objItem.Speed & vbCRLf & _ 
"Status: " & objItem.Status & vbCRLf & _ 
"StatusInfo: " & objItem.StatusInfo & vbCRLf & _ 
"CreationClassName: " & objItem.CreationClassName & vbCRLf & _ 
"TimeOfLastReset: " & objItem.TimeOfLastReset & vbCRLf & _ 
"Connected?: "& objItem.NetConnectionStatus & vbCRLf & _
""
End IF
Next

WScript.Quit

Its still buggy but you get the point.

[Jay]

Still messing with this one.

'  --------------------------------------------------------------' 
Option Explicit
Dim objWMIService, ObjItem
Dim GuyMessage, strComputer, colItems, strStatus
'On Error Resume Next

strComputer = "."

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery ("Select * from Win32_NetworkAdapter",,48)

For Each objItem in colItems
    Select Case objItem.NetConnectionStatus
        Case 0 strStatus = " Disconnected" 
        Case 1 strStatus = " Connecting" 
        Case 2 strStatus = " Connected" 
        Case 3 strStatus = " Disconnecting" 
        Case 4 strStatus = " Hardware not present" 
        Case 5 strStatus = " Hardware disabled" 
        Case 6 strStatus = " Hardware malfunction" 
        Case 7 strStatus = " Media disconnected" 
        Case 8 strStatus = " Authenticating" 
        Case 9 strStatus = " Authentication succeeded" 
        Case 10 strStatus = " Authentication failed" 
        Case 11 strStatus = " Invalid address" 
        Case 12 strStatus = " Credentials required"
    End Select 

  
If objItem.MACAddress <> "" Then
' Remove objItem's that you do not want.
WScript.Echo "Name: " & objItem.Name & vbCRLf  &_ 
"Net Connection ID: " & objItem.NetConnectionID & vbCRLf  & _ 
"Net Connection Status: "& objItem.NetConnectionStatus & strStatus & vbCRLf & _ 
"" & _
"Adapter Type: " & objItem.AdapterType & vbCRLf & _ 
"MAC Address: " & objItem.MACAddress & vbCRLf & _ 
"Availability: " & objItem.Availability & vbCRLf & _
"Computer Name: " & objItem.SystemName & vbCRLf & _ 
"AutoSense: " & objItem.AutoSense & vbCRLf & _ 
"ManagerErrorCode: " & objItem.ConfigManagerErrorCode & vbCRLf & _ 
"ManagerUserConfig: " & objItem.ConfigManagerUserConfig & vbCRLf & _ 
"DeviceID: " & objItem.DeviceID & vbCRLf & _ 
"ErrorCleared: " & objItem.ErrorCleared & vbCRLf & _ 
"ErrorDescription: " & objItem.ErrorDescription & vbCRLf & _ 
"Index: " & objItem.Index & vbCRLf & _ 
"InterfaceIndex: " & objItem.InterfaceIndex & vbCRLf & _ 
"LastErrorCode: " & objItem.LastErrorCode & vbCRLf & _ 
"Manufacturer: " & objItem.Manufacturer & vbCRLf & _ 
"MaxNumberControlled: " & objItem.MaxNumberControlled & vbCRLf & _ 
"MaxSpeed: " & objItem.MaxSpeed & vbCRLf & _ 
"NetworkAddresses: " & objItem.NetworkAddresses & vbCRLf & _ 
"PermanentAddress: " & objItem.PermanentAddress & vbCRLf & _ 
"PNPDeviceID: " & objItem.PNPDeviceID & vbCRLf & _ 
"Power Mngmnt: " & objItem.PowerManagementCapabilities & vbCRLf & _ 
"Power Supported: " & objItem.PowerManagementSupported & vbCRLf & _
"ServiceName: " & objItem.ServiceName & vbCRLf & _ 
"Speed: " & objItem.Speed & vbCRLf & _ 
"Status: " & objItem.Status & vbCRLf & _ 
"StatusInfo: " & objItem.StatusInfo & vbCRLf & _
"CreationClassName: " & objItem.CreationClassName & vbCRLf & _ 
"TimeOfLastReset: " & objItem.TimeOfLastReset & vbCRLf & _ 
""
End IF
Next

WScript.Quit

[Taz]

My code snippet looks like this:

For Each objNA In colNAs
   For i = 0 to totalNics - 1
      If objNA.Name = Left(arrNics(i), Len(objNA.Name)) Then
         If objNA.NetConnectionStatus = 2 Then
            arrLinkStatus(i) = "UP"
         Else
            arrLinkStatus(i) = "DOWN"
         End If
      End If
   Next
Next

Basically, if the NetConnectionStatus is '2' (i.e. Connected) then I report the connection as "UP", otherwise I report it as "DOWN". Works like a champ!

My next challenge will be to get the FQDN for all known IP addresses for every NIC in a Windows machine...

[Jay]

I know that this gives you the fqdn of the system

On Error Resume Next

Const wbemFlagReturnImmediately = &h10
Const wbemFlagForwardOnly = &h20


   strComputer = "."
   Set dict = CreateObject("Scripting.Dictionary")

   Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
   Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration", "WQL", _
                                          wbemFlagReturnImmediately + wbemFlagForwardOnly)

   For Each objItem In colItems
      If Len(objItem.DNSDomain) > 0 And Len(objItem.DNSHostName) > 0 Then
      dict.Add (objItem.DNSHostName & "." & objItem.DNSDomain), dict.Count
      End If
   Next

fqdnArray = dict.Keys
For Each fqdn In fqdnArray
    WScript.Echo fqdn
Next

I can't really see a case when a system would have more than 1 FQDN

This little bit of code gives Domain, system name and user

Set WshNetwork = WScript.CreateObject("WScript.Network")
WScript.Echo "Domain = " & WshNetwork.UserDomain
WScript.Echo "Computer Name = " & WshNetwork.ComputerName
WScript.Echo "User Name = " & WshNetwork.UserName

A useful VBScript forum would be fantastic, we could put bits of code in and other people could then use it as a reference.

[Taz]

Thanks for the FQDN stuff. I'll try it out on site next week. My brain is full now!

[Jay]

Hey Taz, how much experience do you have with VB?

[Taz]

I can't really see a case when a system would have more than 1 FQDN

Jay, I think this could be possible in the following scenario.

A customer has a server with, say two NICs in it. The first NIC is assigned one IP address and the other NIC is assigned another IP address. The DNS could hold two different FQDNs for the same system (one for each NIC). The issue is further compounded by multi-homed NICs and the use of VIPs (virtual IP addresses). In the project i'm working on i've been asked to unravel all of this stuff and it's been a very steep learning curve for me!

[Taz]

Hey Taz, how much experience do you have with VB?

A fair bit these days. I'd consider myself a dabbler rather than a 'proper' programmer, knocking up utilities to extend the capabilities of my companies software products as required. I also dabble in Java. I do have a programming background when I was a systems programmer in the 80's. It was mainly programming in C (also a bit of Algol 68 and Fortran 77!) in those days. I've lost many of my programming skills over the last 15 years or so though.

I'm a disciple of Knuth's "The Art of Computer Programming" books if anyone remembers those.