Simplest way to sync ENTIRE N5200Pro to Remote Disk

[nexusone]

What is the simplest way to sync the entire filesystem of the N5200Pro to a remote disk? I aggregate all the data from my various computers in the house to the N5200Pro but I need to be able to simply kick off a process that will sync all that data to a disk attached to one of my machines.

Everything I can find looks like a hack. NSYNC looks like it might be doable but naturally there is no nsync client from osx or linux.

The thecus backup tool pushes data to the unit which is the opposite of what I need.

Anyone have a simple solution?

Thanks.

[redclawkefar]

hey, i actually use robocopy to sync my systems... both at home and at work. set it up on one system that can access everythng else and set your desired destination for each folder. i can post a sample script if you'd like a little later.

[nexusone]

sure any ideas are appreciated. I've had no luck getting the rsync mod to work. a simple rsync-over-ssh would be just fine. Seems strange to me that thecus doesnt just build rsync in given its near universal use.

In fact the lack of rsync is one of the things keeping my use of these units limited to hobby use rather than for use with my real servers.

[redclawkefar]

k, so i originally posted this on AMD forums which i'll pm you in a bit... seems anti-spam won't let me post here yet.

[redclawkefar]

hmmm... stupid bb code wont let me send a quote via pm

[redclawkefar]

just so i don't have to re-type it all.

my current scripts use a csv file and a bat file to do what i need done. the script auto shutsdown the system at the end so you may want to comment it out. any questions, just ask away. so first up is the bat file:

@echo off
@title Data Backup via Robocopy


::
:: Generates two files, one with the current date and one with the time
:: Then pulls the 3 string value to define the day of week (DOW)
::

cmd /c date /t>DOW
set /p today=<DOW
set DOW=&#37;today:~0,3%
:: echo DOW=%DOW%

cmd /c time /t>TIMENOW
set /p TimeNow=<TIMENOW
set TimeNow=%TimeNow:~0,5%
echo.
echo TimeNow=%TimeNow%

::
:: Using the defined DOW from above decides to run or not run the script.
:: ie. if the IF statement is TRUE it either goes to "end of file" (EOF)
:: or runs the "backupscript"
::

IF "%DOW%" == "Sun" GOTO :EOF
IF "%DOW%" == "Mon" GOTO :backupscript
IF "%DOW%" == "Tue" GOTO :backupscript
IF "%DOW%" == "Wed" GOTO :backupscript
IF "%DOW%" == "Thu" GOTO :backupscript
IF "%DOW%" == "Fri" GOTO :backupscript
IF "%DOW%" == "Sat" GOTO :EOF

:backupscript

echo.
echo To cancel script, CLOSE this window...
echo Waiting to continue...

:timerstart

cmd /c time /t>TIMESTART
set /p TimeStart=<TIMESTART
set TimeStart=%TimeStart:~0,5%
:: echo TimeStart=%TimeStart%

:: IF "%TimeNow%" == "%TimeStart%" GOTO :TIMERSTART

echo.
echo TimeStart=%TimeStart%
echo Timer expired, running backup script...

::
:: pskill will kill/terminate any process you want.
:: Good for terminating outlook for backup purposes. Can be downloaded from M$
::

:: pskill outlook.exe

::
:: Configure log-file location.
:: Located in the same directory as the script with the defined DOW
::

SET LOGLOC=BackupLog_%DOW%.txt

::
:: Checks for the old log-file and deletes it before executing the rest of the script
::

IF EXIST %LOGLOC% (
del %LOGLOC%
)

echo.
echo The %DOW% backup log is now created!


::
:: Configure SOURE and DESTINATION list file location.
:: Must be a comma separated list
:: Located in the same directory as the script
::

SET Src-Dest=BackupList.csv

::
:: Configure Robocopy executable location.
::

SET ROBOLOC=c:\robocopy\robocopy.exe

::
:: Parse the CSV file for source and destination names (file must be closed if using Excel to edit)
:: Where SOURCE is the location of desired file(s) for backup.
:: DESTIN1 is the mapped network or other drive
:: DESTIN2 is the desired destination path of the source file(s)
:: SWITCHES are the desired options for use in Robocopy
:: EXCLUDES are the excluded directories defind in the CSV file
::

FOR /F "tokens=1,2,3,4,5 delims=," %%i in (%Src-Dest%) do (SET source=%%i) & (SET destin1=%%j) & (SET destin2=%%k) & (SET switches=%%l) & (SET excludes=%%m) & (call :next)

GOTO :EOF

:next

IF "%source%"=="End" GOTO :SHUTDOWN

echo.
echo Now backing up source directory: %source%
echo With these excludes set: %excludes%

::
:: Run Robocopy against the list locations with these defined options:
::
:: /MIR : Mirror a directory tree - equivalent to /PURGE plus all subfolders (/E)
:: /V : produce Verbose output log, showing skipped files
:: /NP : Suppress backup progess percentage
:: /XD dirs [dirs]... : eXclude Directories matching given names/paths
:: /ZB : use restartable mode; if access denied use Backup mode
:: /R:n : number of Retries
:: /W:n : Wait time between retries
:: /LOG+ : Append to Output log file
::

:: If backing up over only a single destination, not 5 different day-of-week backups
:: where each day-of-week generates a new directory
:: ie. z:\backup\COMPUTERNAME\Mon
:: z:\backup\COMPUTERNAME\Tue
:: etc
::
:: Use the following robocopy script line
::

:: %ROBOLOC% "%source%" "%destin1%\%destin2%" %switches% /XD %excludes% /LOG+:"%LOGLOC%"

::
:: Comment this line out if not doing a 5 day-of-week backup
::

%ROBOLOC% "%source%" "%destin1%\%computername%\%destin2%" %switches% /XD %excludes% /LOG+:"%LOGLOC%"

GOTO :EOF

:SHUTDOWN

::
:: This shuts down the pc you're running the script on.
:: Useful for the 'end-of-day backup, but I don't want to sit here and wait for it' type of people
:: /s - shuts down system, could use /r if you want to reboot immediately
:: /f - forces shutdown and suppresses the 'End Now' pop-up
:: /t - initiates shutdown in XX seconds
::

shutdown /s /f /t 03

[redclawkefar]

...and the CSV file that BAT script reads:

\\n5200\Vehicles,f:,Vehicles,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
\\n5200\Install_Software,f:,Install_Software,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
\\n5200\Data_Files,f:,Data_Files,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
\\n5200\3d_Max_Work,f:,3d_Max_Work,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
\\n5200\Case_RAW_Photos,f:,Case_Raw_Photos,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
\\storage\Library,f:,Library,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
\\terastation\Storage,f:,terastation,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
C:\Robocopy,f:,Robocopy,/MIR /E /PURGE /V /NP /R:1 /W:1 /TEE
End,,,

[redclawkefar]

...and last... a more detailed description over where i originally posted this on AMD forums:

http://forums.amd.com/forum/messagev...ighlight_key=y

[nexusone]

Ah.... windows.... the one operating system I don't have any of.

What I need is a mechanism that doesnt rely on any shares/mounts and just grabs EVERYTHING from the thecus filesystem in one shot. I'm accustomed to doing this via scp/rsync/ssh+tar and in all cases its as simple as a single line command.

In the examples for rsync setup even that relies upon the shares for configuring the rsyncd. Is there a way to just allow rsync over ssh and keep it simple?

Thanks for going through the trouble to post your scripts. I appreciate the effort to help me out.